; Автор:	shilow@ukr.net
; Дата:		май-июнь 2012
; Название:	avm
; Версия:	1
; Имя файла: 	avm.asm, avm.spl7, avm.lay
; Для AVR:	ATtiny24A
; Тактовая частота: 8MHz, внутренний RC-генератор
; Выполняемые функции: Автомобильный вольтемтр
; см. ReadMe.txt
; схема по "Вариант 5"

;******************************
; инклуды
.nolist
.include "tn24Adef.inc"
.list

;******************************
; опредления
.def job0	= r0
.def job1	= r1
.def job2	= r2
;.def job3	= r3
.def LED1	= r4
.def LED2	= r5
.def LED3	= r6
.def LED4	= r7
.def msrL	= r14
.def msrH	= r15
.def temp	= r16	; рабочая переменная 
.def tmp1	= r17
.def cnt1	= r18
.def cnt2	= r19
.def LEDN	= r20
.def msek5	= r24	; 5-ти мсек интервалы
.def flags	= r25

;******************************
; константы
.equ AtBCD0	= 0	;address of job0
.equ AtBCD2	= 2	;address of job2
.equ AtLED1	= 4	;address of LED1
.equ MSEK100	= 7	; 7bit of flags == 0.1 sek
.equ NEED_DOT	= 6	; нужна точка
.equ DISP_PORT	= PORTA
.equ DISP_DDR	= DDRA
.equ LA1	= 4
.equ LA2	= 5
.equ LA3	= 6
.equ LA4	= 7
.equ SER_PORT	= PORTB
.equ SER_DDR	= DDRB
.equ SCK	= 0
.equ DATA	= 1
.equ LOCK	= 2
.equ T1DIVL	= 0x8F
.equ T1DIVH	= 0xFD	; 0x10000-8MHz/64/200Hz
.equ VREF	= 500	; опорное напряжение * 10 мВ
.equ SPH	= 0x3e
.equ DOT_BIT	= 5	; bit5 -- точка

;******************************
; макросы
; сохраняем в стек SREG и R16
.MACRO PUSHF
	PUSH	R16
	IN	R16,SREG
	PUSH	R16
.ENDM

; восстанавливаем из стека SREG и R16 
.MACRO POPF
	POP	R16
	OUT	SREG,R16
	POP	R16
.ENDM

;******************************
; ячейки в СОЗУ
;.DSEG
;.ORG	SRAM_START
;Display:	.byte 4 ; 4 байта для индикатора

;******************************
; константы в EEPROM
;.ESEG
;smpl1:		.DW	0x0000	; sample 1
;smpl2:		.DB	0x05	; sample 2

;******************************
; память программ
.CSEG
.ORG 0
;******************************
; Таблица векторов прерываний
	rjmp	RESET		; Reset Handler
	reti;jmp	INT0		; IRQ0 Handler
	reti;jmp	PCINT0		; PCINT0 Handler
	reti;jmp	PCINT1		; PCINT1 Handler
	reti;jmp	WDT		; Watchdog Interrupt Handler
	reti;jmp	TIM1_CAPT	; Timer1 Capture Handler
	reti;jmp	TIM1_COMPA	; Timer1 Compare A Handler
	reti;jmp	TIM1_COMPB	; Timer1 Compare B Handler
	rjmp	TIM1_OVF	; Timer1 Overflow Handler
	reti;jmp	TIM0_COMPA	; Timer0 Compare A Handler
	reti;jmp	TIM0_COMPB	; Timer0 Compare B Handler
	reti;jmp	TIM0_OVF	; Timer0 Overflow Handler
	reti;jmp	ANA_COMP	; Analog Comparator Handler
	rjmp	ADCC		; ADC Conversion Handler
;	rjmp	EE_RDY		; EEPROM Ready Handler
;	rjmp	USI_STR		; USI STart Handler
;	rjmp	USI_OVF		; USI Overflow Handler

;******************************
;;;;; Первичная инициализация
RESET:	ldi	temp,high(RAMEND); Main program start
	out	SPH,temp
	ldi	temp,low(RAMEND)
	out	SPL,temp; Set Stack Pointer to top of RAM
; выкл. аналог, компаратор 
	ldi	temp,1<<ACD
	out	ACSR,temp
; настроим АЦП. опора - Vcc, канал 1, непрерывное преобразование. temp=0b00100010
	ldi	temp,1<<MUX0
	out	ADMUX,temp
	ldi	temp,(1<<ADEN)|(1<<ADSC)|(6<<ADPS0)
	out	ADCSRA,temp
; timer1 - частота 200 гц, при тактовой 8МГц, прескалер=64, TCNT1L=0xс0, TCNT1H=0x63
	ldi	temp,(3<<CS10)
	out	TCCR1B,temp
	ldi	temp,T1DIVH
	out	TCNT1H,temp
	ldi	temp,T1DIVL
	out	TCNT1L,temp	; запустили таймер 1
; разрешаем прерывание от таймера
	ldi	temp,1<<TOIE1
	out	TIMSK1,temp
; init
	ldi	LEDN,0b11101111	; первый индикатор
	ldi	temp,(1<<LA1)|(1<<LA2)|(1<<LA3)|(1<<LA4)
	out	DISP_DDR,temp
	out	DISP_PORT,temp
	ldi	temp,(1<<SCK)|(1<<DATA)|(1<<LOCK)
	out	SER_DDR,temp
	ldi	msek5,20
	clr	YH
	ldi	YL,AtLED1	; загружаем адрес 1-го индикатора
	ldi	temp,0x30
	mov	LED1,temp
	mov	LED2,temp
	mov	LED3,temp
	mov	LED4,temp
; Enable interrupts
	sei
;******************************
;;;;; Основная программа
BEGIN:

	sbrs	flags,MSEK100	; пора производить измерения?
	rjmp	MLBL1		; нет
	;!! ADATE@ADCSRA==1, при ADTS@ADCSRB==0 -- запуск free running mode
	clr	msrL
	clr	msrH		; очистили хранилище результата
	ldi	cnt2,16		; загрузили счётчик измерений
	sbi	ADCSRA,ADATE	; запуск free running mode
	sbi	ADCSRA,ADIE	; разрешаем прерывания от АЦП
	sbi	ADCSRA,ADSC	; запуск нов. преобразования 
ML1:	rjmp	PC+1		; nop x 2 -- 1 world 2 takta
	tst	cnt2		; гоняем пустой цикл пока будут происходить 16 измерений
	brne	ML1
	cbi	ADCSRA,ADIE	; запрещаем прерывания от АЦП
	cbi	ADCSRA,ADATE	; stop free running mode
	lsr	msrH
	ror	msrL
	lsr	msrH
	ror	msrL		; поделили результат на 2^2
	; теперь множим на Vref и делим на 4096
	ldi	temp,low(VREF)
	ldi	tmp1,high(VREF)
	rcall	MPY16U
	lsr	job1		; выбросили job0 == поделили на 256
	ror	job0
	lsr	job1
	ror	job0
;;	lsr	job1
;;	ror	job0
;;	lsr	job1
;;	ror	job0		; доделили на 16, итого поделили на 4096
;	ldi	cnt1,4
;ML2:	lsr	job2
;	ror	job1
;	dec	cnt1
;	brne	ML2
	mov	msrL,job0
	mov	msrH,job1	; в MSR - напряжение в 10мВ
;!!! умножить на входной делитель
;; -- не доделили на 4 == умножили теперь на 4.
;; в реале нужно будет множить например на 400 и делить на 100 -- под реальный делитель.
; тут можно добавить коррекцию усиления.
	rcall	bin2BCD16
	; 4 значащих цифры в job1:job0
	ldi	XL,AtLED1
	clr	XH
	mov	temp,job1
	swap	temp
	rcall	OUT_NIBBL	; ниббл 3, десятки
	mov	temp,job1
	sbr	flags,1<<NEED_DOT
	rcall	OUT_NIBBL	; ниббл 2, единицы
	cbr	flags,1<<NEED_DOT
	mov	temp,job0
	swap	temp
	rcall	OUT_NIBBL	; ниббл 1, десятые
	mov	temp,job0
	rcall	OUT_NIBBL	; ниббл 0, сотые
MLBL1:

;******************************
; делать нечего - поспим...
	ldi	temp,1<<SE
	out	MCUCR,temp	; простой режим сна
	sleep			; спим.
	clr	temp
	out	MCUCR,temp	; со сна

	rjmp	BEGIN

;******************************
;;;;; Подпрограммы

;******************************
; выдаёт в порт 8 бит из temp, портит cnt1
LEDOUT:	ldi	cnt1,8		; счетчик бит
LO1:	cbi	SER_PORT,SCK	; SCK=0
	lsl	temp		; старший бит в перенос
	brcc	LO0		; если в переносе 0 — перейти
	sbi	SER_PORT,DATA	; выдали 1
	rjmp	LOE
LO0:	cbi	SER_PORT,DATA	; выдали 0
LOE:	sbi	SER_PORT,SCK	; SCK=1, сдвиг данных
	dec	cnt1
	brne	LO1
	ret

;******************************
;** переводим младший ниббл temp в код для 7-сгм инд и кладём его в озу по адр Y
OUT_NIBBL:
	ldi	ZL,low(LEDnd*2)
	ldi	ZH,high(LEDnd*2); адрес кодов для индикатора
	andi	temp,0x0F	; отсекаем ст ниббл. получаем смещение
	add	ZL,temp
	adc	ZH,XH		; добавили смещение
	lpm	temp,Z		; прочитали код
	sbrc	flags,NEED_DOT	; нужна точка?
	cbr	temp,1<<DOT_BIT	; включаем точку
	st	X+,temp		; записали код в позицию индикатора
	ret

;******************************
; перемножение двух 16-разрядных величин, результат 3 байта, рабочая
; множимое msrH:msrL, множитель tmp1:temp, результат job2:job1:job0
; использует cnt1
MPY16U:	clr	job2		;clear 1 highest bytes of result
	ldi	cnt1,16		;init loop counter
m16u_1:	lsr	tmp1
	ror	temp
	brcc	noad8		;if bit 0 of multiplier set
	add	job1,msrL	;add multiplicand Low to byte 1 of res
	adc	job2,msrH	;add multiplicand high to byte 2 of res
noad8:	ror	job2		;shift right result byte 2
	ror	job1		;rotate right result byte 1
	ror	job0		;rotate result byte 0 and multiplier Low
	dec	cnt1		;decrement loop counter
	brne	m16u_1		;if not done, loop more
	ret

;******************************
;* This subroutine converts a 16-bit number (msrH:msrL) to a 5-digit 
;* packed BCD number represented by 3 bytes (job2:job1:job0).
;* MSD of the 5-digit number is placed in the lowermost nibble of job2.
bin2BCD16:
	ldi	cnt1,16		;Init loop counter
	clr	job2		;clear result (3 bytes)
	clr	job1
	clr	job0
	clr	ZH		;clear ZH
bBCDx_1:lsl	msrL		;shift input value
	rol	msrH		;through all bytes
	rol	job0
	rol	job1
	rol	job2
	dec	cnt1		;decrement loop counter
	brne	bBCDx_2		;if counter not zero
	ret			;   return
bBCDx_2:ldi	ZL,AtBCD2+1	;Z points to result MSB + 1
bBCDx_3:ld	temp,-Z		;get (Z) with pre-decrement
	subi	temp,-$03	;add 0x03
	sbrc	temp,3		;if bit 3 not clear
	st	Z,temp		;	store back
	ld	temp,Z		;get (Z)
	subi	temp,-$30	;add 0x30
	sbrc	temp,7		;if bit 7 not clear
	st	Z,temp		;	store back
	cpi	ZL,AtBCD0	;done all three?
	brne	bBCDx_3		;loop again if not
	rjmp	bBCDx_1


;******************************
;;;;; Обработчики прерываний

TIM1_OVF:	; Timer1 Overflow Handler
; выводим данные на 7-ми сегментные индикаторы
; отсчитываем 100 мсек интервал для запуска измерений
	PUSHF

	dec	msek5
	brne	T1L1
	ldi	msek5,20
	sbr	flags,1<<MSEK100

T1L1:
	;***************************
	; вывод на индикатор очередной цифры
	ldi	temp,0xF0
	out	DISP_PORT,temp	; погасили все индикаторы
	cbi	SER_PORT,LOCK	; подгтовили защёлку
	ld	temp,Y+		; в темп - текущая цифра, адрес=+1
	rcall	LEDOUT		; выпихнули очередной байт в регистр
	sbi	SER_PORT,LOCK	; из 0 в 1 -- защёлкивание данных в регистре
	mov	temp,LEDN
	andi	temp,0xF0
	out	DISP_PORT,temp	; включаем очередной индикатор
	lsl	LEDN		; сдвинули - следующий индикатор
	brlo	T1L2		; вышли за границы? проверка 
	ldi	LEDN,0b11101111	; да, загружаем начальное значение
	ldi	YL,AtLED1	; загружаем адрес 1-го индикатора
T1L2:
	ldi	temp,T1DIVH
	out	TCNT1H,temp
	ldi	temp,T1DIVL
	out	TCNT1L,temp	; перезапустили таймер 1

	POPF
	reti

; ADC Conversion Handler
; суммируем результаты измерений, уменьшаем счётчик.
ADCC:	in	temp,ADCL
	add	msrL,temp
	in	temp,ADCH
	adc	msrH,temp
	dec	cnt2
	reti

;***************************
; байты для вывода 0-9 на индикаторы с ОА, без точки. точка вкл установкой бита 5
LEDnd:	.DB	0x30,0xF3,0x2A,0xA2,0xE1,0xA4,0x24,0xF2,0x20,0xA0

.exit

INT0:		; IRQ0 Handler
	reti

PCINT0:		; PCINT0 Handler
	reti

PCINT1:		; PCINT1 Handler
	reti

WDT:		; Watchdog Interrupt Handler
	reti

TIM1_CAPT:	; Timer1 Capture Handler
	reti

TIM1_COMPA:	; Timer1 Compare A Handler
	reti

TIM1_COMPB:	; Timer1 Compare B Handler
	reti

TIM0_COMPA:	; Timer0 Compare A Handler
	reti

TIM0_COMPB:	; Timer0 Compare B Handler
	reti

TIM0_OVF:	; Timer0 Overflow Handler
	reti

ANA_COMP:	; Analog Comparator Handler
	reti

EE_RDY:		; EEPROM Ready Handler
	reti

USI_STR:	; USI STart Handler
	reti

USI_OVF:	; USI Overflow Handler
	reti

;
.exit